Tablón de anuncios
 Otros: Macros para el wow
- Escrito por Salhamedon
 el 13 de julio de 2007 a las 17:31
Saludos a todos Hermanos:
Acabo de saber como se pueden hacer de nuevo las macros en el WOW, y es una cosa que estaba deseando hacer porque yo antes lo usaba mucho con lo que simplificaban la jugabilidad muchísimo. Desde que salió la versión 2.0 del WOW no había forma de que me funcionara las macros complicadas y es por ello, y porque toda la hermandad puede aprovechar estos conocimientos, que hoy expongo este curso avanzado de macros WOW 2.0.
Si quereis saber mas podéis entrar donde saque la informacion: http://forums.wow-europe.com/thread.html?topicId=184878573&sid=4
Lo que yo he hecho es copiar/pegar resumiendo el contenido y no quiero quitar el merito a los que lo hicieron y los que lo tradujeron al castellano. Queda dicho.
1. Introducción
En WoW 2.0, las macros y los addon han cambiado drásicamente. Blizzard ha añadido nuevas y emocionantes funcionalidades a las macros en WoW 2.0, un conjunto de opciones condicionales para /cast y también para /use, /target, /focus, /assist, /stopmacro, /cancelaura, /userandom, /castrandom, /castsequence,
/click, y varios comandos /pet*. Con esta guía se intentará mostrar cómo usarlas.
Usar /cast es muy simple. El formato es /cast <NombreHechizo> (que utilizará el rango máximo del hechizo), o /cast <NombreHechizo>(Rango n). Ejemplo:
/cast Sanación Superior
/cast Sanación Superior(Rango 3)
"Si tenéis abierto el libro de hechizos mientras escribís la macro, pulsando con SHIFT+hechizo en el libro, os escribirá el nombre del hechizo incluyendo el rango".
En el nuevo sistema este formato funciona igual, pero ahora puedes incorporar opciones quedan más flexibilidad a tus /cast. El nuevo formato para '/cast' es: /cast [<primer conjunto de opciones>] <primer hechizo>; [<segundo conjunto de opciones>] <segundo hechizo>; [<tercer conjunto de opciones>] <tercer hechizo>; ...
Y funciona de la siguiente manera: se evalua el primer conjunto de opciones. Si se cumplen, se lanza el primer hechizo. Si NO se cumple, se evalua el segundo conjunto de condiciones, que de cumplirse lanza el segundo hechizo, Y así sucesivamente. Hay que tener en cuenta que SOLO uno de los hechizos será lanzado (el primero que cumpla las condiciones) y la macro pasará a la siguiente linea.
Esta es la lista de Opciones disponibles:
help - Es 'verdadero' si el objetivo es amistoso
harm - Es 'verdadero' si el objetivo es hostil
combat - Es 'verdadero' ei estás en combate
stance o stance:# - Es 'verdadero' si estás en una actitud (o forma) cualquiera o en una concreta.
stealth - Es 'verdadero' si estás en Sigilo.
modifier o modifier:shift|ctrl|alt - Es 'verdadero' si la tecla indicada está apretada cuando se ejecuta el comando
equipped:<item> - Es 'true' si el objeto está equipado. Item puede ser cualquier hueco válido de inventario, clase de objeto o subclase
target=<unit> - Opción especial. Cambia el objeto del hechizo al especificado por 'unit' (ver abajo)
actionbar:<number> - Es 'verdadero' si la barra de acción activa es la especificada
pet:<tipo pet O nombre pet> - Es 'verdadero' if the pet exists. Coge tipos de mascota (Buho, Oso, Imp) o nombre (Fluffy, MrBigglesworth). Sin modificador (tan solo [pet]) es 'verdadero' si CUALQUIER mascota existe
mounted, swimming, flying - Es 'verdadero' si estás montado, nandado o volando
indoors, outdoors - Es 'verdadero' si estás en interiores o exteriores respectivamente
button:<#> - Es 'verdadero' si el botón usado para activar la macro es el especificado, por defecto 1 (ver abajo)
channeling:<hechizo> - Es 'verdadero' si estás canalizando el hechizo especificado. Si no se especifica hechizo, es 'verdero' si se está canalizando cualquier hechizo
exists y dead - Es 'verdadero' si tu objetivo está muerto, o existe
party - Es 'verdadero' si el objetivo es miembro de tu grupo
raid - Es 'verdadero' si el objetivo es miembro de tu grupo o banda
group - Es 'verdadero' si estás en un grupo
group:party/raid - Es 'verdadero' si estás en el tipo de grupo indicado (grupo/banda)
Nuevo Comando de Macro
----------------------
/castsequence - Lanza un conjunto predeterminado en secuencia (ver abajo)
# show <hechizo> - Muestra el estado de cooldown en el icono del hechizo correspondiente.
# showtooltip <hechizo> - Muestra la información (tooltip) del hechizo especificado
Algunos truquitos:
- Puedes añadir no al comienzo de cada opción para invertir la condición (excepto con target). Por ejemplo, si ponemos [nocombat] sólo funcionará si NO estamos en combate.
- Separar opciones con una coma ',' funciona como una sentencia 'Y', por lo tanto sólo funciona si se cumplen ambas condiciones.
- Separar opciones con una barra '/' funciona como una sentencia 'O' por lo tanto sólo funciona si se cumplen cualquiera de las condiciones. Esto solo funciona para los argumentos de una opción y no entre opciones (por lo tanto [stance:1/2] es válido, y [combat/help] no).
- Seleccionar la interrogación '?' como icono en el Editor de Macro, fuerza a que se utilice el icono del hechizo correspondiente.
2. Ejemplos y Actitudes (stances)
Algunos ejemplos que pueden servir de ayuda:
/cast Curación Superior - Macro sencilla para lanzar Curación Superior sobre un objetivo.
/cast [help] Curación Superior - Se añade una opción. Lanza la Curación si el objetivo es amistoso.
/cast [help] Curación Superior; Mamporro - Se añade un segundo hechizo. Dado que el segundo no lleva opción, se lanzará si la primera opción no se cumple.
/cast [help, combat] Sanación relámpago; [help, nocombat] Sanación Superior; Mamporro - Esta macro lanzará Sanación replámpago si el objetivo es amistoso y estamos en combate (no el objetivo). Si no estamos en combate y el objetivo es amistoso, lanzará Sanación Superior. Si ninguna de las anteriores se cumple (el objetivo no es amistoso), lanzará Mamporro.
/cast [help] Sanación Superior; [harm, combat] Mamporro; [harm, nocombat] Tortura mental - Esta lanzará Sanación Superior si el objetivo es amistoso, Mamporro si estamos en combate o Tortura mental si no estamos en combate.
/cast [stealth] Emboscar; Puñalada - Esta usará Emboscada si el jugador está en Sigilo y puñalada si no lo está.
/cast [nostealth] Backstab; Ambush - Exactamente igual pero puesto de manera diferente.
/cast [actionbar:1] Sanación Superior; [actionbar:2] Mamporro - Si la barra de acción activa es la #1 lanza Sanación Superior y si es la 2, Mamporro (con la 3 o más no hace nada).
/cast [harm] Polimorfia
/stopmacro [noharm]
/p Ovejeando %t! NO TOCAR!
Esta macro lanza Polimorfia si el objetivo es hostil, entonces detiene la macro si el objetivo NO es hostil (eje. si la oveja no funcionó). Entonces anuncia al grupo que el objetivo ha sido ovejeado. Nótese que debido al comando '/stopmacro', si el objetivo no se ovejea, no se dará el mensaje al grupo (evitando spam innecesario).
/cast [nopet] Llamar a mascota; Revivir Mascota - Esta macro llama a tu mascota si no tienes ninguna, en otro caso intenta revivirla.
/cast [pet:owl] Dive; [pet:cat] Dash; [pet] Growl - Esta macro usará Dive si tienes un búho, Dash si tienes un gato, o Growl si no es ninguna de las anteriores.
/cast [pet:Voidwalker] Sacrificio; [pet:succubus] Seducción - Un brujo usará sacrificio si tiene sacado el Abisario y Seducción si tiene la súcubo.
/use [nomounted,outdoors] Black War Steed Bridle - Esta macro intenta usar la montura si se está en exterior y sin montar.
/cast [target=pet,dead] Revivir mascota; [nopet] Llamar a mascota; Aliviar mascota - Revive la mascota si está muerta, llama la mascota si no está sacada, o cura a la mascota.
/cast [group:party] Luminosidad Arcana; Intelecto Arcano - Lanzará Luminosidad Arcana si estás en grupo, sino lanzará Intelecto.
/cast [raid] Bendición de Sabiduría - lanzará Bendición de Sabiduría si tu objetivo está en la misma banda que tú.
-------------------
Actitudes (stances):
-------------------
Las Actitudes funcionan de la misma manera. Si no se proporcionan ningún número, será 'verdadero' si el jugador está en cualquier Actitud. (Nota: los guerreros SIEMPRE están en una Actitud). Si se determina un número se evaluará si esa forma o actitud es la activa.
Cada clase tiene diferentes números para sus actitudes. He aquí una lista:
Guerrero - Stance:1 Combate / Stance:2 Defensiva / Stance:3 Rabiosa
Sacerdote - Stance:1 Forma de Sombra
Druida - Stance:1 Oso / Stance:2 Acuática / Stance:3 Felina / Stance:4 Viaje / Stance:5 Lechúcico/Árbol
Pícaro - Stance:1 Sigilo
Las auras de Paladín ya no se tratan como Actitudes por el sistema de Macro.
Hay que tener en cuenta que si se salta una Actitud (supongamos un guerrero que no hizo la misión de la Actitud Defensiva), los números se desplazan, ej.: la actitud rabiosa tendría el número 2.
Algunos ejemplos:
/cast [nostance] Forma de Oso - Si no estás en ninguna forma pone la forma de Oso.
/cast [stance:1] Abrumar; [stance:2] Hender armadura; [stance:3] Torbellino - Lanza abrumar si se está en Actitud de combate, Hender Armadura en defensiva y Torbellino en rabiosa.
/cast [stance:1] Growl; [stance:3] Claw - Lanza Growl si se está en forma de oso, o Claw en forma de felino.
/cast [nostance:3] Cat Form - Te pondrá en forma felina si no lo estás. Si ya estás en forma felina, esto NO te quitará la forma.
3. Opción 'equipped' (equipado)
La opción [equipped] funciona de la misma manera aunque tiene truquillo. El argumento puede ser un hueco del inventario (ver abajo), un tipo de objeto, o un subtipo. Para una lista completa de tipos y subtipos mirar aquí: http://www.wowwiki.com/ItemType
Lista de Huecos de Inventario:
Two-Hand (2 Manos)
Bag (Bolsa)
Shirt (Camisa)
Chest (Pechera)
Back (Capa)
Feet (Pies)
Finger (Anillo)
Hands (Manos)
Head (Cabeza)
Held In Off-hand (Se sostiene en la zurda)
Legs (Piernas)
Neck (Cuello)
Ranged (A distancia)
Chest (Pechera)
Off Hand (Zurda)
Shoulder (Hombros)
Tabard (Tabardo)
Thrown (para el hueco de arrojadizas)
Trinket (Alhaja)
Waist (Cintura)
One-Hand (Una mano)
Main Hand (Mano principal)
Off Hand (Mano secundaria)
Wrist (Muñeca)
Algunos ejemplo:
/cast [equipped:Two-Handed Swords] Golpe Mortal; Golpe Heróico - Usa Golpe si se sostiene una espada de 2 manos.
/cast [equipped:Two-Handed Swords/Two-Handed Maces/Two-Handed Axes/Polearms] Mortal Strike - Aquí se utiliza el modificador '/' para indicar una condición 'O'. Aquí se usa Golpe Mortal si CUALQUIERA de los tipos está equipado.
/cast [equipped:Shields] Azote de escudo - Lanzará Azote de escudo si se tiene un escudo equipado.
/cast [equipped:Shields, equipped:Daggers] Embate con escudo - Lanzará Embate con escudo sólo si se tiene un escudo y una daga equipados.
/cast [noequipped:Shields, equipped:Off Hand] Desenfreno - Lanzará Desenfreno si NO tiene equipado un escudo, Y tienes cualquier cosa puesta en la mano secundaria. Esto en teoría se activa cuando sostienes 2 armas.
4. Opciones de Objectivo (target) y Botones
La opción [button:<x>] funciona de manera similar al modificador de botón. Normalmente, si haces click-izquierdo en un botón, hace la acción correspondiente que esté en ese hechizo, en nuestro caso una macro. Sin embargo, si estableces la opción de botón, puedes cambiar el comportamiento de esa macro.
El botón por defecto es 1, el botón izquierdo del ratón. Nótese que al activar una macro a través de una tecla, lo trata como si se hubiese pulsado el botón izquierdo. Los botones son:
1 o LeftButton (izquierdo)
2 o RightButton (derecho)
3 o MiddleButton (central)
4 o Button4
5 o Button5
... o cualquiera de los botones remapeados por las cabeceras de estado seguro (secure state headers). Para ser honesto no tengo mucha idea de qué significa esto. Tan solo me limito a citar a Slouken (Slouken es el responsable de Blizzard de UI).
/cast [button:2,target=player] SanaciónRelámpago; [help] Sanación Relámpago - Esta macro lanzará Sanación Relámpago en un objetivo amistoso, o si pulsaste el botón derecho, lo lanzará sobre tí mismo.
La opción [target=unit] es una opción especial. No evalua si es 'verdadero' o 'falso', sino que cambia el objetivo al que va destinado el siguiente hechizo Y el objetivo de otras opciones. "Unit" sólo puede ser un tipo de unidad válido como "player", "target", "targettarget", "party1", "party1target", etc etc. Consultar los tipos de unidad aquí: http://www.wowwiki.com/UnitId. Tiene además la ventaja de que no cambia tu selección de objetivo actual.
Hay que tener en cuenta que cada hechizo tiene su objetivo por defecto a "target". Por lo tanto:
/cast [help] Sanación Superior
es lo mismo que
/cast [target=target, help] Sanación Superior
Mientras no se ponga la opción [target=unit], el objetivo por defecto será el actual. Posibles ejemplos de [target=unit]:
/cast [target=player] Sanación Relámpago - Esta macro siempre lanzará sobre tí Sanación Relámpago. Nótese de que tu objetivo actual no cambia.
/cast [help] Sanación Relámpago; [target=targettarget] Sanación Relámpago - Esto lanzará Sanación Relámpago sobre tu objetivo si es amistoso O sobre el objetivo de tu objetivo si no lo es.
/cast [help, combat] Sanación Relámpago; [help, nocombat] Sanación Superior; [target=targettarget, help, combat] Sanación Relámpago; [target=player] Sanación Superior. - Esto hará una de estas acciones: 1) Lanza Sanación Relámpago si el objetivo es amistoso y estás en combate, 2) lanza Sanación Superior si es amistoso pero NO estás en combate, 3) Sanación Relámpago en el objetivo de tu objetivo si estás en combate y esa unidad es amistosa, o si no se cumple ninguna de las anteriores lanzará Sanación Superior sobre tí mismo.
Ten en cuenta de que el id de unidad "none" funcionar como si no tuvieras objetivo. Por ejemplo:
/cast [target=none] Disipar Magia - Esto disiparía magia y te preguntaría por un objetivo (con el cursor brillante), independientemente de a quién tengas seleccionado.
Voy a hacer un inciso para explicar como funciona un objetivo especial: 'focus', ya que en la guía original no se explica. Con la opción 'focus' se puede "grabar" un objetivo para usarlo posteriormente como target en una macro (o en la misma). Para que funcione, en primer lugar hay que establecer el focus sobre un objetivo con el comando /focus y a partir de ahí ya puede usarse como 'target=focus' en las opciones de una macro. Un ejemplo claro puede ser para la oveja de un mago:
/focus target [nocombat, harm]
/cast [target=focus] Polimorfia
En primer lugar establece el objetivo actual como foco sino estamos en combate y el objetivo es hostil. A continuación haría oveja a este objetivo. Pero la verdadera gracia de esta macro es al usarla la siguiente vez: si tenemos otro objetivo diferente a la oveja (al que le estemos haciendo DPS), re-ovejearía al objetivo del principio sin tener perder el que tenemos ahora y sin preocuparnos de seleccionar de nuevo la oveja.
5. Lanzar Sequencia (Castsequence)
Nuevo comando: /castsequence
Hay un nuevo comando en WoW 2.0 llamado /castsequence. Permite establecer una serie de hechizos para lanzarlos uno detrás de otro en cada click consecutivo de la macro. El formato es:
/castsequence [<optiones>] reset=<#>/target/combat/alt/shift/ctrl <hechizo1>, <hechizo2>, <hechizo3>
"¿Huh?¿Qué has dicho?"
Que estableces una lista de hechizos y la primera vez que haces click en la macro se lanza el primer hechizo. La siguiente vez que haces click, lanzará el segundo hechizo, y así sucesivamente. Cuando se lanza el último de la lista se vuelve al principio.
"Todavía no te sigo."
Vale, digamos que tienes un mago. A veces necesitas hacer Nova de Escarcha y Traslación para alejarte. Como no se pueden hacer ambos a la vez, estableces una secuencia para hacerlo.
/castsequence Nova de Escarcha, Traslación
Y aquí lo tienes. En el primer click has hecho Nova de Escarcha, entonces haces click de nuevo y te trasladas.
"¿Y qué pasa si la Nova de Escarcha está en cooldown? ¿Hace la Traslación en su lugar o se lo salta y hace la Traslación en el siguiente click?"
Ni una ni otra. Si falla un hechizo (por cooldown, por fuera de rango, sin maná, lo que sea), la secuencia NO continúa al siguiente hehcizo. El siguiente siguiente click tratará de hacer Nova de Escarcha de nuevo. (NOTA: Si te resiste, esquivan, param, etc NO es considerado como fallo. La habilidad/hechizo pasará, simplemente falló el tiro).
"¿Qué pasa si no estoy en combate? No quiero gastar la Nova de Escarcha si no estoy peleando"
Puedes seguir usando las mismas opciones de macro (sin embargo, no se puede poner un conjunto de opciones para cada hechizo individual, solo para toda la secuencia en conjunto).
/castsequence [combat] Nova de Escarcha, Traslación
"Eh, estaba bromeando sobre eso del combate. Vale, entonces ¿qué pasa si hago la Nova pero decido no hacer la traslación? La próxima vez que quiera usar la Nova ¿estaré pillado para usar la Traslación?"
No es problema. Podemos usar la opción 'reset'. Dado que normalmente la Nova tiene un cooldown de 24 segundos, ponemos que la secuencia se resetee después de 24 segundos sin usarse la macro.
/castsequence reset=24 Nova de Escarcha, Traslación
La primera vez que haces click, hace Nova. Si decides no hacer Traslación, después de 24 segundos se resetea y vuelve a la Nova y además estará de nuevo sin cooldown para usarse. ¡Brillante!
"Entonces, ¿el contador se resetea siempre después de 24 secs pase lo que pase?"
No siempre. Es como un temporizador de timeout por desuso. Si no usas la macro *para nada* en la duración del contador, se resetea. Pero si continuas pulsando la macro, cada pulsación reseteará el contador, incluso si falla el lanzamiento. Por eso no se puede hacer algo como '/castsequence reset=30 Ola explosiva, Explosión Arcana, Explosión Arcana, Explosión Arcana, Explosión Arcana' porque nunca se resetearía de nuevo a Ola explosiva hasta que lo huebieras dejado sin usar 30 segundos.
"Si vale, muy bien...pero es que yo soy un brujo, tío."
Por supuesto que sí. Bien, como brujo, estoy seguro de que lanzas los mismos 3 DoTs una y otra vez. Ahora puedes hacer una secuencia para ellos y ahorrar esos espacios de botones.
/castsequence Corrupción, Inmolar, Maldición de Agonía
Ahí lo tienes, ahora puedes pulsar ese botón 3 veces y lanzas los 3 DoTs.
"¿Y qué pasa si muero antes de lanzar los 3? ¿Me quedo de nuevo estancado en la secuencia? ¡y no quiero poner un temporizador!"
Vale, vale, podemos usar otras opciones. Si pones 'reset=target' cada vez que cambias de objetivo, resetea la secuencia al principio. También puedes usar 'reset=combat', y se resetea cada vez que dejes el combate. Si usas el operador '/' (¿lo recuerdas de antes?) puedes combinar distintas opciones de reset.
/castsequence reset=combat/target Corrupción, Inmolar, Maldición de Agonía
Aquí, cada vez que cambies de objetivo (como si por ejemplo el antiguo objetivo muere y quieres empezar en uno nuevo=, o cada vez que dejes el combate (a lo mejor el bicho muere antes de lanzar todos los DoTs), resetea la secuencia por tí, dejandola lista para empezar.
"¿Qué pasa si quier resetear manualmente mi secuencia, eh?"
Bien, puedes añadir un modificador para hacerlo así:
/castsequence reset=combat/target/shift Corrupción, Inmolar, Maldición de Agonía
Ahora si mantienes pulsado shift mientras le das a la macro, automáticamente la reseta al inicio y lanza Corrupción.
"¡Vale, genial, creo que ya lo tengo! Dame un segundo para hacer mis nuevas macros..... ¡hecho!"
Excelente, Me alegra haber sido de ayuda.
"Entoces... ¿hace un duelo?"
Mmm, no gracias, no hago duelos con brujos.
"Bah, eres un blandengue"
6. Ejemplos
Macros Generales:
/use [target=player] Venda Gruesa de Tela Abisal - Esta macro siempre usará la venda sobre uno mismo sea cual sea su objetivo actual.
Macros de Guerrero:
------------------
Interceptar/Cargar: usa uno u otro según la situación o cambia a la actitud correcta para hacerlo.
/cast [nocombat,stance:1] Cargar; [combat,nostance:3] Actitud Rabiosa; [nocombat,nostance:1] Actitud de Combate; [combat,stance:3] Interceptar
Macro genérica de Actitud : Reemplaza <Habilidad Actitud *> por la que quieras.
/cast [stance:1] <Habilidad Actitud Combate>; [stance:2] <Habilidad Actitud Defensiva>; [stance:3] <Habilidad Actitud Rabiosa>
Abrumar: Una macro sencila para Abrumar
/cast [stance:1] Abrumar; Actitud de Combate
Macros de Mago
-----------------
Pyro/Bola de fuego: Lanza Piroexplosión si no estás en combate (como apertura), y de lo contrario, bola de fuego.
/cast [nocombat] Piroexplosión; Bola de fuego
Polimorfear al Foco: Siempre polimorfea al objetivo del Foco.
/cast [target=focus] Polimorfia
Macros de Sacerdote
-----------------------
Sanación Superior al objetivo actual del boss o al objetivo actual.
/cast [target=targettarget, help] Sanación Superior; [help] Sanación Superior
Macros de Cazador
---------------------
Alimentar/Curar mascota según el estado del combate.
/cast [combat] Aliviar Mascota; [nocombat] Alimentar a mascota
/use [nocombat] <escribe objeto comida>
Y aqui termina todo, la idea es que ahora vayamos investigando y escribamos aqui nuestras macros para poder ayudar al resto de hermanos... ahi queda eso XD
| Comentarios – 5 comentarios |
|
Escrito por Salhamedon
el 13 de julio de 2007
a las 17:52 > |
Y como ante todo hay que dar ejemplo empiezo con las macros que he creado para el druida:
Para empezar hechos los buffos a mi y a la peña:
/castsequence reset=target Espinas, Marca de lo Salvaje - Pongo espinas primero que se gasta antes, para ir hechandolo siempre
/castsequence reset=180 Presteza de la Naturaleza, Augurio de claridad Estos son mis buffos que me lo puedo tirar cada 3 minutos, por eso tengo el reset a 180 segundos
Despues tengo este de esta forma:
/cast [group] Don de lo Salvaje - Para no hecharlo a no ser que estemos en grupo, que este me cuesta dinero XD
En forma de León tengo el kit completo en tres macros:
1) /cast [combat]Triturar; [nostealth,nocombat] Acechar; [stealh] Abalanzarse - De esta forma me hago invisible, me abalanzo para marearlo y le trituro.
2) /castsequence reset=target Arañazo, Zarpa, Zarpa - De esta forma le voy atacando consiguiendo puntos de combo dando tiempo a que se gaste el arañazo.
3) /castsequence reset=target Destripar, Mordedura feroz- Y así realizo los combos, primero pongo destripar para que se vaya gastando con el tiempo, y despues mordeduro feroz para rematar.
Pues aqui os dejo los macros que tengo por ahora, como vaya haciendo los iré poniendo aquí XD. |
Escrito por Yirkash 
el 24 de agosto de 2007
a las 09:48 < > |
Canalizaciones continuas
_________________________________________________________
Drain Soul
Esta macro hace 2 cosas, 1 que spameando el boton te asegures que solo recastees hasta q el channeling termina y si le das con el boton derecho para cualkier cosa que estes haciendo pero eso ya es mas opcional
#showtooltip
/stopattack [button:RightButton]
/stopcasting [button:RightButton]
/cast [nochanneling:Drain Soul] Drain Soul
Drain mana
Te ahorra la cantidad exagerada de los 5 puntos de interrumpir el channeling, solo spameando el boton no recasteas hasta que termine, asegurando un drain continuo.
#showtooltip
#show
/cast [nochanneling:Drain mana] Drain mana
Drain life
Ídem que con el mana
#showtooltip
#show
/cast [nochanneling:Drain life] Drain life
Pets
_________________________________________________________
Controla tu pet
Esta es muy ÚTIL!!!! Manda al pet (imp) cerca del boss sin sacarlo de phase y sin que lo lleves tu
/petstay
/petattack
/petpassive
Darkpackt
Usa lifetap si tu pet a muerto o no la tienes
#show
#showtooltip
/cast [pet] Dark pact; Life tap
Todas las pets, 1 boton
Click - imp
Click derecho - void
CTRL+click - sucubo
ALT+click - felhunter
/cast [modifier:ctrl]Summon Succubus(Summon); [button:2]Summon Voidwalker(Summon); [modifier:alt]Summon Felhunter(Summon); summon imp(summon)
Spells en un botón
_________________________________________________________
Escudos
Botón derecho - escudo clásico
Click normal - escudo nuevo (ahorra 1 boton en la barra :P)
#show Fel armor
#showtooltip Fel armor
/cast [button:2] Demon armor; Fel armor
Fears
Lo mismo que para el escudo, yo personalmente el fear d area lo uso poco
#showtooltip
#show Howl of terror
/cast [button:2] Howl of terror; Fear
Maldiciones
Click - Maldición de las sombras
Click derecho - Maldición de los elementos
#showtooltip
#show curse of shadow
/cast [button:2] curse of the elements; Curse of shadow
Anuncios
_________________________________________________________
Summon
Anuncia el summon a quien es, a donde y en el canal correspondiente
#showtooltip
#show
/script local C; if(GetNumRaidMembers()==0) then C = "PARTY" else C = "RAID" end SendChatMessage("Invocando a %t en << "..GetMinimapZoneText().." >>. Pinchad el portal!.", C)
/cast Ritual of summoning
Piedras de vida
Anuncia el casteo de piedras de vida
#showtooltip
/script local C; if(GetNumRaidMembers()==0) then C = "PARTY" else C = "RAID" end SendChatMessage("Piedras... << Pinchad el pozo!!! >>", C)
/cast Ritual of souls
Piedra de alma
Anuncia a quien pones la piedra de alma
#showtooltip Master Soulstone
#show Master Soulstone
/use Master soulstone
/script local C if(GetNumRaidMembers()==0) then C = "PARTY" else C = "RAID" end SendChatMessage("<< SS puesta en [%t] >>", C)
Secuencias
_________________________________________________________
Castea magias en un orden, es decir, pulsas una vez lanza la primera, pulsas otra vez lanzas la seguna, etc...
Secuencia de DoTs
#showtooltip
/castsequence reset=target/combat Curse of Agony, Corruption o al gusto Siphon life, etc...
Secuencia fuego destrucción
#show
/castsequence reset=target/combat Immolar,Incinerate,Conflagrate
Control de mobs
_________________________________________________________
Banish y rebanisea tu marca sin cambiar de target (Alt apretado borra el focus)
#showtooltip
/clearfocus [modifier:alt]
/focus [target=focus,noexists]; [target=focus,dead]
/cast [target=focus,] Banish;
Seduce y reseduce tu marca sin cambiar de target (Alt apretado borra el focus)
#showtooltip
/clearfocus [modifier:alt]
/focus [target=focus,noexists]; [target=focus,dead]
/clearfocus [target=focus,help]
/cast [pet:succubus,target=focus,exists,harm] Seduction; Seduction
Fear a tu marca sin cambiar de target (Alt apretado borra el focus)
#showtooltip
/clearfocus [modifier:alt]
/focus [target=focus, noexists] [target=focus, dead] [target=focus, help]
/stopmacro [target=focus, noexists]
/cast [target=focus] fear
NOTA: están en inglés para el cliente en inglés, en castellano solo hay q cambiar el nombre de los conjuros a su nombre en castellano.
Sacado del foro oficial del WoW. |
Escrito por Yirkash
el 24 de agosto de 2007
a las 09:57 < > |
Otra macro del mismo asunto del foro del WoW, muy útil, publicada por Milú:
/StopMacro [pet:nosuccubus]
/focus [modifier:alt] target
/StopMacro [modifier:alt]
/cast [target=focus,pet:succubus] Seduction
/focus [target=focus,dead]
/cast [target=focus] Curse of Shadows
Antes del combate targeteas al mob designado para el seduce y pulsas la tecla alt+la macro, esto hará que el target se quede guardado. Una vez realizado el pull, tengas a quien tengas targeteado, pulsando otra vez la macro (sin la tecla alt) Casteará sobre el mob el CoS y la Súcubo lo seducira, mientras tu doteas, Nukeas o drenas la vida al primer mob para morir.
Cuando termine el primer seduce pulsas otra vez la macro, y, sin cambiar tu objetivo actual, la súcubo reseducirá al mob.
Si en mitad de un combate deseas cambiar el objetivo del seduce has de targetear al nuevo objetivo y apretar la tecla Alt+macro, y otra vez la macro sin ALT para seducir y dotear con CoS. |
Escrito por Yirkash
el 16 de septiembre de 2007
a las 03:23 < > |
Una macro que te da las coordenadas de tu posición, para la gente que no quiera instalarse add-ons que te las indiquen:
/script px,py=GetPlayerMapPosition("player")
/script DEFAULT_CHAT_FRAME:AddMessage(format("[ %s ] %i , %i",GetZoneText(),px*100,py*100)); |
Escrito por Salhamedon
el 11 de octubre de 2007
a las 18:05 < |
Ooooh, ese último me ha encantado, me lo guardo XDDD. A ver si tengo algo mas de tiempo y me invento alguna mas. |
| Total: 5 comentarios |
Volver al tablón de anuncios...
Volver a la página principal...
|
